@echo off
title 电脑小保姆
color 1f
:start
echo.
echo 请选择要进行的操作，然后单击回车：
echo.
echo ****************************************************
echo.
echo 1 -- 清理电脑垃圾 2 -- 查看系统时间
echo.
echo 3 -- 定时关机设定 4 -- 计时关机设定
echo.
echo 5 -- 删除关机任务 6 -- 查看关机任务
echo.
echo 7 -- 注销当前用户 0 -- 退出这个程序
echo.
echo ****************************************************
:set
SET a=
SET /P a=选择:
rem 设定变量"a"为用户输入的字符
IF NOT '%a%'=='' SET a=%a:~0,1%
ECHO.
IF /I '%a%'=='1' goto 1
IF /I '%a%'=='2' goto 2
IF /I '%a%'=='3' goto 3
IF /I '%a%'=='4' goto 4
IF /I '%a%'=='5' goto 5
IF /I '%a%'=='6' goto 6
IF /I '%a%'=='7' goto 7
IF /I '%a%'=='0' goto 0
rem 如果输入的字符不是0-7,将返回重新输入
echo %a% 选择无效，请重新输入：
echo.
goto set
:1
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.log
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
del /f /q %userprofile%\cookies\*.*
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"
cls
echo 恭喜！清除垃圾完成啦
echo. &pause
cls
goto start
:2
echo 如果不想重设时间，直接单击回车后继续...
echo.
time
echo. &pause
cls
goto start
:3
echo 请输入关机时间,(如12:00:00)
set shutdowntime=
set /p shutdowntime=
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
echo %shutdowntime% 不是标准的时间格式,请重新输入
echo.
goto 3
:ok
echo.
echo 恭喜，设定完毕!
echo. &pause
cls
goto start
:4
echo 您想要多少秒后关机
echo (若设定后要取消,单击"确定"后按Ctrl+C键两次)
set timed=
set /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
echo %timed% 是无效的关机时间,请重新输入
echo.
goto 4
:5
at /del /y
echo 恭喜，定时关机已成功取消!
echo. &pause
cls
goto start
:6
at
echo. &pause
cls
goto start
:7
logoff
:0
exit
这是我现在在用的..自己加了点东西...呵呵,发上来大家共享一下啊..一样,记事本保存成 .bat 文件就可以了...
